Perlでの継承とは？

普通、オブジェクトのクラスは、他のオブジェクトのクラスを継承することができます。
クラスの継承ができるということは、オブジェクトの抽象化と具象化に繋がり、結果的にオブジェクトの部品化を促進します。

Perlでのオブジェクトのクラスも継承ができます。
Perlでの継承は、baseプラグマを使用します。

以下のサンプルは、testx01.plが継承なしで、testx02.plが継承ありのケースです。
継承ありのtestx02.plでは、DateString2クラス（サブクラス）を使用していますが、このクラスはDateStringクラス（スーパークラス）を継承しています。

見た目、DateString2クラスのコンストラクタnewを起動していますが、実はDateString2クラスにはコンストラクタnewはありません。
これは、継承したDateStringクラスのコンストラクタnewを起動しているのです。

また、DateStringクラスとDateString2クラスには同じ名前のto_stringメソッドがあります。
to_stringメソッドは、コンストラクタnewと違い、DateString2クラス自身のto_stringメソッドが起動されます。

つまり、スーパークラスのメソッドの上にサブクラスのメソッドが乗ってしまったのです。
これをオーバーライドという。

testx01.pl

#!/usr/bin/perl
use strict;
use DateString;

my $date = DateString->new;
print $date->to_string;

testx02.pl

#!/usr/bin/perl
use strict;
use DateString2;

my $date = DateString2->new;
print $date->to_string;

DateString.pm

package DateString;
use strict;
sub new {
    my $class = shift; # 第一引数は、クラス名が渡される。
    my $time = shift || time();
    return bless { time => $time }, $class; # blessしたリファレンスを返す。
}
sub to_string {
    my $self = shift;
    return scalar localtime $self->{time};
}
1;

DateString2.pm

package DateString2;
use base DateString; # DateStringクラスの継承
use strict;
use constant DATE_FORMAT => '%04d/%02d/%02d %02d:%02d:%02d (%s)';

sub to_string {
    my $self = shift;
    my @loaclt = localtime $self->{time};
    return sprintf DATE_FORMAT,
           $loaclt[5] + 1900,
           $loaclt[4] + 1,
           $loaclt[3],
           $loaclt[2],
           $loaclt[1],
           $loaclt[0],
           (qw(日 月 火 水 木 金 土))[$loaclt[6]];
}
1;

処理結果

C:\Documents and Settings\xxx\DateString>perl testx01.pl
Fri Feb  8 22:23:41 2008
C:\Documents and Settings\xxx\DateString>perl testx02.pl
2008/02/08 22:23:47 (金)