Attribute::Protectedのソースを読んでみました！

本ブログの読者の方からAttribute::Protectedモジュールを教えて頂いて、ソースを見たのですがチンプンカンプンだったので、少し調べてみました。
ちなみに、本モジュールは、Javaライクなアクセス修飾子（Public,Private,Protected）をPerlのsubに実装するもののようです。
とにかく、このソースを読むとPerlの柔軟さがわかって、すごくPerlの勉強になりましたよ！

◆ソースプログラム（Attribute::Protected）

package Attribute::Protected;

use 5.006;
use strict;
use warnings;

our $VERSION = '0.03';

use Attribute::Handlers;

sub UNIVERSAL::Protected : ATTR(CODE) {
    my($package, $symbol, $referent, $attr, $data, $phase) = @_;
    my $meth = *{$symbol}{NAME};
    no warnings 'redefine';
    *{$symbol} = sub {
	unless (caller->isa($package)) {
	    require Carp;
	    Carp::croak "$meth() is a protected method of $package!";
	}
	goto &$referent;
    };
}

sub UNIVERSAL::Private : ATTR(CODE) {
    my($package, $symbol, $referent, $attr, $data, $phase) = @_;
    my $meth = *{$symbol}{NAME};
    no warnings 'redefine';
    *{$symbol} = sub {
	unless (caller eq $package) {
	    require Carp;
	    Carp::croak "$meth() is a private method of $package!";
	}
	goto &$referent;
    };
}

sub UNIVERSAL::Public : ATTR(CODE) {
    my($package, $symbol, $referent, $attr, $data, $phase) = @_;
    # just a mark, do nothing
}

1;
__END__

http://cpansearch.perl.org/src/MIYAGAWA/Attribute-Protected-0.03/lib/Attribute/Protected.pm

◆使用例

  package SomeClass;
  use Attribute::Protected;

  sub foo  : Public    { }
  sub _bar : Private   { }
  sub _baz : Protected { }

  sub another {
      my $self = shift;
      $self->foo;		# OK
      $self->_bar;		# OK
      $self->_baz;		# OK
  }

  package DerivedClass;
  @DerivedClass::ISA = qw(SomeClass);

  sub yetanother {
      my $self = shift;
      $self->foo;		# OK
      $self->_bar;		# NG: private method
      $self->_baz;		# OK
  }

  package main;

  my $some = SomeClass->new;
  $some->foo;		# OK
  $some->_bar;		# NG: private method
  $some->_baz;		# NG: protected method

http://cpansearch.perl.org/src/MIYAGAWA/Attribute-Protected-0.03/lib/Attribute/Protected.pm

とりあえず、以下が分からなかったので調べて見ました。

• サブルーチン属性
• Attribute::Handlersモジュール
• UNIVERSAL
• シンボルテーブル登録
• gotoで関数リファレントに飛ぶ

まず、「サブルーチン属性」と「Attribute::Handlersモジュール」は以下で理解する。

• http://blog.yappo.jp/yappo/archives/000347.html
• http://blog.yappo.jp/yappo/archives/000348.html

要は、サブルーチンにサブルーチン属性を指定すると、本処理とは別の処理ができるようになるのです。

UNIVERSALは、すべてのクラスのルートとなるクラスで、ここでPublic,Private,Protectedの各メソッドを定義する。
すると、これらがサブルーチン属性で起動されるようになる。

『*{$symbol} = sub {…}』は、呼ぼうとしている関数のあるパッケージのシンボルテーブル登録で、呼ぼうとしている関数名を含む型グロブをハッシュキーとして一連のCarp::croak等と、そして、最後に『goto &$referent;』で本来の処理へGoToしているロジックを、関数リファレンスとして、シンボルテーブルに再定義しています（意味通じるかな…）。

とにかく、CODE実行時（実際はコンパイルの最後？）にサブルーチン属性で起動され、上記のように実行されてから、置き換えた後の自関数を実行する。
つまり、サブルーチン属性での起動でシンボルテーブル登録の関数を置き換えるて、従来の処理の他に＋αの処理をすることにより実現しているようです。
これは、すごい発想力ですね。

あと、ベアワードの「NAME」は、シンボルテーブルから関数名をもとめるためのハッシュキーになるようです。
また、「caller」と「caller->isa」は、察しの通り、呼ばれた関数や継承した関数が分かるようです。

ということで、まだまだ未熟ですが、ここまで調べてみました。
しかし、サブルーチン属性は、タイ変数と双璧をなす、Perlのヘンタイ仕様ですね！

シンボルテーブルについては、以下を参照のこと。

• http://www.geocities.jp/ky_webid/perl5/036.html
• http://d.hatena.ne.jp/bingo_nakanishi_perl/20090205/1233840768

励みにしますので、本ブログの応援クリックも、よろしくお願いします。